Import Export champs Objet

Bonjour,
l’import/export de champs objet semble ne pas fonctionner correctement.
En utilisant l’interface basique 4D (Fichier/Export, puis Import avec format application 4D), les champs objet importés sont Null
Quelle est votre expérience sur ce sujet ?
Merci !

Salut Marc,
j’ai testé un export/import d’enregistrement avec un champ de type objet, ça fonctionne :

$nombre:=Random
$chaine:=Generate UUID
$bool:=($nombre%2=0)
$obj:=New object("nombre";$nombre;"chaine";$chaine;"booleen";$bool)
$json:=JSON Stringify($obj)
	//créer un enregistrement
CREATE RECORD([Table2])
[Table2]champObj:=$obj
[Table2]champTxt:=$chaine
[Table2]champAlpha:=$chaine
SAVE RECORD([Table2])
	//exporter l'enregistrement
$stamp:=Replace string(Timestamp;":";"-";*)
$stamp:=Replace string($stamp;".";"-";*)
$path_t:=System folder(Desktop)+"__"+$stamp+".txt"
SET CHANNEL(10;$path_t)  //créer doc
ASSERT(ok=1)
SEND RECORD([Table2])
SET CHANNEL(11)  //fermer doc
ASSERT(Test path name($path_t)=Is a document)
	//importer comme nouvel enregistrement
SET CHANNEL(10;$path_t)  //ouvrir doc
ASSERT(ok=1)
RECEIVE RECORD([Table2])
SET CHANNEL(11)  //fermer doc
	//contrôles
ASSERT($chaine=[Table2]champTxt)
ASSERT($chaine=[Table2]champAlpha)
ASSERT($json=JSON Stringify([Table2]champObj))

Par contre avec le dialogue d’export “basique” je n’arrive strictement à rien. J’ai remarqué par exemple que, si je peux ajouter un champ objet aux champs à exporter, il dégage dès que je touche au menu du format de sortie. Il est possible que je n’ai rien compris… peu m’importe, ça fait belle lurette que je suis brouillé avec cet export.