Process windows

fr: Une méthode pour collecter les numéros de fenêtres d’un process donné. Commentaires et suggestions bienvenus.
en: A method to get window(s) reference(s) from a given process. Please feel free to comment and/or make it better.

<code 4D>
//Pss_windowsGet (io_o)
//get windows references from a given process
//io object props:
// in:
// $io.processNumber : process number, longint
// $io.processName : process name, text
// out:
// $io.windows : collection, longint (Null if no window found)
// If both processNumber and processName are send,
// processNumber is used and processName is ignored

//examples:
// C_OBJECT($io)
// $io:=New object
// $io.processName:=“myProcessName”
// Pss_windowsGet ($io)

// C_OBJECT($io)
// $io:=New object
// $io.processNumber:=1
// Pss_windowsGet ($io)

C_OBJET($1;$io) //in out

C_COLLECTION($win_c)
C_ENTIER LONG($pss_l;$i_l)

ASSERT(Nombre de paramètres>0)
ASSERT($1#Null;“Null in out object $1”) //do New object before
$io:=$1
Au cas ou
: ($io.processNumber#Null)
$pss_l:=$io.processNumber
: ($io.processName#Null)
$pss_l:=Chercher process($io.processName)
Fin de cas
TABLEAU ENTIER LONG($win_al;0)
Si ($pss_l#0)
LISTE FENÊTRES($win_al)
Boucle ($i_l;Taille tableau($win_al);1;-1)
Si ($pss_l#Process de la fenêtre($win_al{$i_l}))
SUPPRIMER DANS TABLEAU($win_al;$i_l)
Fin de si
Fin de boucle
Fin de si
$win_c:=Créer collection
TABLEAU VERS COLLECTION($win_c;$win_al)
$io.windows:=$win_c
//_
</code 4D>
.c4d version:
https://forums.4d.com/4DBB_Main/x_User/4467/files/28441146.zip

De l’art de ne pas mettre en valeur ce que l’on vend. :mrgreen:
N’est-il pas grand temps que 4D s’occupe des balises de code du forum ? :cry: