Références tables et champs html

La campagne de renommage étant lancée, j’avais besoin de retrouver les références de tables et de champs dans le dossier web d’une base. La méthode qui suit peigne le dossier web puis copie dans le presse papier les fichiers où ces références existent.
Bilan des courses, je n’ai presque rien trouvé car le collègue-faiseur-de-ouèbe préfère les tableaux :mrgreen:
<code 4D>
//Renommages_web
//cherche les noms de tables et de champs dans les pages HTML pouvant être
// impactés par renommages tables et champs

//Tokens :
// http://doc.4d.com/4Dv17R2/4D/17-R2.1720/Utiliser-des-tokens-dans-les-formules.300-3857588.fr.html
// Commande 4D * Chaine(a) * :Cxx * String:C10(a) * xx est le numéro de la commande
// Table * [Employés] * :xx * [Employés:1] * xx est le numéro de la table
// Champ * [Employés]Nom * :xx * [Employés:1]Nom:2 * xx est le numéro du champ

//C_ENTIER LONG(count_l) //décommenter pour compter nombre d’appels récursifs
C_TEXTE($1;$webFolder_t)
C_POINTEUR($2;$arr_p)
$params_l:=Nombre de paramètres
Si ($params_l=0) //dossier racine (en dur, adapter selon le besoin)
//count_l:=1
$webFolder_t:=Convertir chemin POSIX vers système("/Users/arnaud/Developpements/zeDossierDeZeBase/dossierWeb/")
Sinon
$webFolder_t:=$1
$arr_p:=$2
//count_l:=count_l+1
Fin de si

$extentionsATraiter_t:=".htm,.html,.shtm,.shtml,"
TABLEAU TEXTE($result_at;0)
TABLEAU ENTIER LONG($pos_al;0)
TABLEAU ENTIER LONG($len_al;0)
LISTE DES DOCUMENTS($webFolder_t;$document_at;Chemin absolu+Ignorer invisibles)
$rx_t:="(\[\w{1,31}(:\d{1,3})?\]\w{1,31}(:\d{1,3})?|\[\w{1,31}(:\d{1,3})?\])" //"[table]champ" ou “[table]”
Boucle ($i_l;1;Taille tableau($document_at))
$doc_t:=$document_at{$i_l}
$ext_t:=Fs_extRead ($doc_t)+"," //lit l’extension
Si (Position($ext_t;$extentionsATraiter_t)>0)
$data_t:=Document vers texte($doc_t;“utf-8”;Document inchangé)
$start_l:=1
Tant que (Trouver regex($rx_t;$data_t;$start_l;$pos_al;$len_al))
$found_t:=Sous chaîne($data_t;$pos_al{0};$len_al{0})
AJOUTER À TABLEAU($result_at;$doc_t+"\t"+$found_t)
$start_l:=$pos_al{0}+$len_al{0}
Fin tant que
Fin de si
Fin de boucle

//ajouter les références trouvées au tableau retour
Si ($params_l>1)
Boucle ($i_l;1;Taille tableau($result_at))
AJOUTER À TABLEAU($arr_p->;$result_at{$i_l})
Fin de boucle
Fin de si

//sous dossiers
LISTE DES DOSSIERS($webFolder_t;$folder_at)
Boucle ($i_l;1;Taille tableau($folder_at))
Renommages_web ($webFolder_t+$folder_at{$i_l}+Séparateur dossier;->$result_at) //récursif
Fin de boucle

Si ($params_l=0) //fin traitement
FIXER TEXTE DANS CONTENEUR(Str_implode (->$result_at;"\r"))
TRACE
Fin de si

//_
</code 4D>